Lancer de rayons¶

Introduction¶

Une des tâches les plus courantes dans le développement de jeu est de lancer un rayon (ou un objet de forme personnalisée) et de vérifier ce qu'il touche. Cela permet de mettre en place des comportements complexes, de l'IA, etc... Ce tutoriel explique comment faire cela en 2D et en 3D.

Godot stocke toutes les informations de jeu de bas niveau dans des serveurs, alors que la scène n'est qu'une interface. En tant que tel, le ray casting est généralement une tâche de niveau inférieur. Pour les raycasts simples, les nœuds tels que RayCast et RayCast2D fonctionneront, car ils retourneront à chaque image le résultat du raycast.

Souvent, cependant, le ray casting doit être un processus plus interactif, donc il doit exister un moyen de le faire par le code.

Espace¶

Dans le monde physique, Godot stocke toutes les informations de collision et de physique de bas niveau dans un espace. L'espace 2d actuel (pour la physique 2D) peut être obtenu en accédant à CanvasItem.get_world_2d().space. Pour la 3D, c'est Spatial.get_world().space.

L'espace résultant RID peut être utilisé dans PhysicsServer et Physics2DServer respectivement pour 3D et 2D.

Accéder à l'espace¶

La physique de Godot s'exécute par défaut dans le même thread que la logique du jeu, mais peut être définie pour fonctionner sur un thread séparé afin de fonctionner plus efficacement. De ce fait, le seul moment où l'accès à l'espace est sûr est pendant le Node._physics_process() callback. L'accès depuis l'extérieur de cette fonction peut entraîner une erreur due à un espace verrouillé.

Pour effectuer des requêtes dans l'espace physique, il faut utiliser Physics2DDirectSpaceState et PhysicsDirectSpaceState.

Utilisez le code suivant en 2D :

func _physics_process(delta):
    var space_rid = get_world_2d().space
    var space_state = Physics2DServer.space_get_direct_state(space_rid)

public override void _PhysicsProcess(float delta)
{
    var spaceRid = GetWorld2d().Space;
    var spaceState = Physics2DServer.SpaceGetDirectState(spaceRid);
}

Ou plus directement :

func _physics_process(delta):
    var space_state = get_world_2d().direct_space_state

public override void _PhysicsProcess(float delta)
{
    var spaceState = GetWorld2d().DirectSpaceState;
}

Et en 3D :

func _physics_process(delta):
    var space_state = get_world().direct_space_state

public override void _PhysicsProcess(float delta)
{
    var spaceState = GetWorld().DirectSpaceState;
}

Requête Raycast¶

Pour effectuer une requête 2D raycast, la méthode Physics2DDirectSpaceState.intersect_ray() peut être utilisée. Par exemple :

func _physics_process(delta):
    var space_state = get_world_2d().direct_space_state
    # use global coordinates, not local to node
    var result = space_state.intersect_ray(Vector2(0, 0), Vector2(50, 100))

public override void _PhysicsProcess(float delta)
{
    var spaceState = GetWorld2d().DirectSpaceState;
    // use global coordinates, not local to node
    var result = spaceState.IntersectRay(new Vector2(), new Vector2(50, 100));
}

Le résultat est un dictionnaire. Si le rayon n'a rien touché, le dictionnaire sera vide. S'il a heurté quelque chose, il contiendra des informations sur la collision :

if result:
    print("Hit at point: ", result.position)

if (result.Count > 0)
    GD.Print("Hit at point: ", result["position"]);

Le dictionnaire result en cas de collision contient les données suivantes :

{
   position: Vector2 # point in world space for collision
   normal: Vector2 # normal in world space for collision
   collider: Object # Object collided or null (if unassociated)
   collider_id: ObjectID # Object it collided against
   rid: RID # RID it collided against
   shape: int # shape index of collider
   metadata: Variant() # metadata of collider
}

Les données sont similaires dans l'espace 3D, en utilisant les coordonnées Vector3.

Exceptions de collision¶

Un cas d'utilisation courant pour le ray casting est de permettre à un personnage de recueillir des données sur le monde qui l'entoure. Un problème avec cela est que ce même personnage a un collisionneur, donc le rayon ne détectera que le collisionneur de son parent, comme le montre l'image suivante :

Pour éviter l'auto-intersection, la fonction intersect_ray() peut prendre un troisième paramètre facultatif qui est un tableau d'exceptions. Voici un exemple d'utilisation à partir d'un nœud KinematicBody2D ou de tout autre nœud d'objet de collision :

extends KinematicBody2D

func _physics_process(delta):
    var space_state = get_world_2d().direct_space_state
    var result = space_state.intersect_ray(global_position, enemy_position, [self])

class Body : KinematicBody2D
{
    public override void _PhysicsProcess(float delta)
    {
        var spaceState = GetWorld2d().DirectSpaceState;
        var result = spaceState.IntersectRay(globalPosition, enemyPosition, new Godot.Collections.Array { this });
    }
}

Le tableau des exceptions peut contenir des objets ou des RIDs.

Masque de collisions¶

Bien que la méthode des exceptions fonctionne bien pour exclure le corps parent, elle devient très peu pratique si vous avez besoin d'une liste large et/ou dynamique d'exceptions. Dans ce cas, il est beaucoup plus efficace d'utiliser le système de masques/couche de collision.

Le quatrième argument facultatif de intersect_ray() est un masque de collision. Par exemple, pour utiliser le même masque que le corps parent, utilisez la variable membre collision_mask :

extends KinematicBody2D

func _physics_process(delta):
    var space_state = get_world().direct_space_state
    var result = space_state.intersect_ray(global_position, enemy_position,
                            [self], collision_mask)

class Body : KinematicBody2D
{
    public override void _PhysicsProcess(float delta)
    {
        var spaceState = GetWorld2d().DirectSpaceState;
        var result = spaceState.IntersectRay(globalPosition, enemyPosition,
                        new Godot.Collections.Array { this }, CollisionMask);
    }
}

Voir Exemple en code pour plus de détails sur la manière de régler le masque de collision.

Ray casting 3D à partir de l'écran¶

Le Ray casting depuis l'écran vers l'espace physique 3D est utile pour la sélection d'objets. Il n'est pas nécessaire de le faire car CollisionObject a un signal "input_event" qui vous indiquera quand il a été cliqué, mais si vous souhaitez le faire manuellement, voici comment.

Pour lancer un rayon depuis l'écran, vous avez besoin d'un nœud Camera. Une Camera peut être dans deux modes de projection : perspective et orthogonale. Pour cette raison, l'origine et la direction du rayon doivent être obtenues. Ceci est dû au fait que l'origin change en mode orthogonal, alors que la normal change en mode perspective :

Pour l'obtenir à l'aide d'une caméra, le code suivant peut être utilisé :

const ray_length = 1000

func _input(event):
    if event is InputEventMouseButton and event.pressed and event.button_index == 1:
          var camera = $Camera
          var from = camera.project_ray_origin(event.position)
          var to = from + camera.project_ray_normal(event.position) * ray_length

private const float rayLength = 1000;

public override void _Input(InputEvent @event)
{
    if (@event is InputEventMouseButton eventMouseButton && eventMouseButton.Pressed && eventMouseButton.ButtonIndex == 1)
    {
        var camera = GetNode<Camera>("Camera");
        var from = camera.ProjectRayOrigin(eventMouseButton.Position);
        var to = from + camera.ProjectRayNormal(eventMouseButton.Position) * rayLength;
    }
}

Rappelez-vous que pendant _input(), l'espace peut être verrouillé, donc en pratique cette requête doit être exécutée dans _physics_process().